автор перевода: Koval Alexander	Предыдущая | Следующая | Оглавление

TextField.styleSheet

Доступность

Flash Player 7.

Синтаксис

my_txt.styleSheet = TextField StyleSheet

Описание

Свойство; назначает style sheet текстовому полю определенному my_txt. Для информации по созданию style sheets, смотри TextField.StyleSheet class и Formatting text with Cascading Style Sheets в Using ActionScript во Flash.

style sheet связаный с текстовым полем может быть изменен в любое время. Если используемый style sheet изменился, то текстовое поле перерисуется используя новый style sheet. style sheet может быть установлен в null или undefined что бы удалить style sheet. Если используемый style sheet удалили, текстовое поле перерисуется без style sheet.

Пример

Следующий пример создает новое текстовое поле в режиме реального времени, названое news_txt. Кнопки на сцене, css1_btn, css2_btn и clearCss_btn, применяются для изменения style sheet в news_txt или удаления style sheet из текстового поля. Добавьте следующий код в ваш FLA или AS файл:

this.createTextField("news_txt", this.getNextHighestDepth(), 0, 0, 300, 200);
news_txt.wordWrap = true;
news_txt.multiline = true;
news_txt.html = true;
var newsText:String = "<p class='headline'>Description</p> Method; starts loading the CSS file into styleSheet. The load operation is asynchronous; use the <span class='bold'>TextField.StyleSheet.onLoad</span> callback handler to determine when the file has finished loading. <span class='important'>The CSS file must reside in exactly the same domain as the SWF file that is loading it.</span> For more information about restrictions on loading data across domains, see Flash Player security features.";
news_txt.htmlText = newsText;

css1_btn.onRelease = function() {
  var styleObj:TextField.StyleSheet = new TextField.StyleSheet();
  styleObj.onLoad = function(success:Boolean) {
    if (success) {
      news_txt.styleSheet = styleObj;
      news_txt.htmlText = newsText;
    }
  };
  styleObj.load("styles.css");
};

css2_btn.onRelease = function() {
  var styleObj:TextField.StyleSheet = new TextField.StyleSheet();
  styleObj.onLoad = function(success:Boolean) {
    if (success) {
      news_txt.styleSheet = styleObj;
      news_txt.htmlText = newsText;
    }
  };
  styleObj.load("styles2.css");
};

clearCss_btn.onRelease = function() {
  news_txt.styleSheet = undefined;
  news_txt.htmlText = newsText;
};

Следующие стили применяются к текстовому полю. Сохраните следующие два CSS файла в той же директории что и FLA или AS файл который вы создали ранее:

/* in styles.css */
.important {
  color: #FF0000;
}
.bold {
  font-weight: bold;
}
.headline {
  color: #000000;
  font-family: Arial,Helvetica,sans-serif;
  font-size: 18px;
  font-weight: bold;
  display: block;
}

/* in styles2.css */
.important {
  color: #FF00FF;
}
.bold {
  font-weight: bold;
}
.headline {
  color: #00FF00;
  font-family: Arial,Helvetica,sans-serif;
  font-size: 18px;
  font-weight: bold;
  display: block;
}

Посмотреть комментарии LiveDocs		Предыдущая | Следующая | Оглавление